CATCH block may only be associated with an undoable block. (

EDIT:  better code image:  http://www.timcollins.com/images/catch_OE_error_14140.png  - sorry, color highlighting after [Insert Code using Syntax Highlighter] looked good in "Preview" mode, but not so good in the post.

Hello All,

Error makes sense and thus "do" requires an "on error" phrase.  All good.

... as long as "on error"s undo directive does not have a label ...  ???

• change "do" to a "repeat", all good
• remove labels, put undo statement (with same directives) in catch processing, all good
• make explicit transaction, all good - guess "on error" alone not good enough?

Am I missing an intricate detail of "on error"?  Bug?

Thanks,

Tim

Example illustrating the error (OE 11.6):

block-level on error undo, throw.
using Progress.Lang.AppError.

define variable var1 as character no-undo.

MAIN_BLK:
repeat:
   update var1.
   do on error undo MAIN_BLK, retry MAIN_BLK:
      run pValidation(input var1).
      catch ae as AppError:
          message ae:getMessage(1) view-as alert-box.
      end catch.
   end.
end.

procedure pValidation:
   define input parameter pVar as character no-undo.
   if pVar = "A" then
      undo, throw new AppError("We don't like 'A'",999).
end.

All the following compile/run successfully.

block-level on error undo, throw.
using Progress.Lang.AppError.

define variable var1 as character no-undo.

MAIN_BLK:
repeat:
   update var1.
   INNER_BLK:
   repeat on error undo MAIN_BLK, retry MAIN_BLK:
      run pValidation(input var1).
      leave INNER_BLK.
      catch ae as AppError:
          message ae:getMessage(1) view-as alert-box.
          undo MAIN_BLK, retry MAIN_BLK.
      end catch.
   end.
end.

procedure pValidation:
   define input parameter pVar as character no-undo.
   if pVar = "A" then
      undo, throw new AppError("We don't like 'A'",999).
end.

block-level on error undo, throw.
using Progress.Lang.AppError.

define variable var1 as character no-undo.

MAIN_BLK:
repeat:
   update var1.
   do on error undo, leave:
      run pValidation(input var1).
      catch ae as AppError:
          message ae:getMessage(1) view-as alert-box.
          undo MAIN_BLK, retry MAIN_BLK.
      end catch.
   end.
end.

procedure pValidation:
   define input parameter pVar as character no-undo.
   if pVar = "A" then
      undo, throw new AppError("We don't like 'A'",999).
end.

block-level on error undo, throw.
using Progress.Lang.AppError.

define variable var1 as character no-undo.

MAIN_BLK:
repeat:
   update var1.
   do TRANSACTION on error undo MAIN_BLK, leave MAIN_BLK:
      run pValidation(input var1).
      catch ae as AppError:
          message ae:getMessage(1) view-as alert-box.
      end catch.
   end.
end.

procedure pValidation:
   define input parameter pVar as character no-undo.
   if pVar = "A" then
      undo, throw new AppError("We don't like 'A'",999).
end.