Infragistics WinGrid, Outlook GroupBy, and ProBindingSource

Does invoking the RefreshAll() method on the ProBindingSource after deleting the row any difference?

Von meinem iPad gesendet

From what I can see in Infragstics fora this is likely expected behavior. (Note that I did not find any direct mentioning of delete, but group positions are not changed automatically when the underlying cell is changed.)

I may be wrong, so feel free to report it to Support or enter an enhancement request, but if this is expected then you are using the right RefreshSortPosition() method to deal with this, but your code is traversing the rows of UltraGrid:Rows collection which will return the top level of GroupBy rows if GroupBy rows             are being used.

You should get the expected behavior if you call RefreshSortPosition on the row that has the wrong record in it (because you deleted the record that the grid used to sort and group it).  You can get a collection of the rows on the band through the Band:GetRowEnumerator(). The code below shows how to traverse the list, but it also illustrates a problem since the resort will (can?) cause the MoveNext to throw an exception. It should work if you call it after the query has opened (with "ttTest" as parameter), but I woud try to find a way to avoid the exception. (copy the list, or use Band:ChildRow to get the first and the equivalent of a "next-sibling" method if it exists).

 method public void resortBand(bandKey as char):
      define variable enumerator as System.Collections.IEnumerator  no-undo.
      define variable gridRow as Infragistics.Win.UltraWinGrid.UltraGridRow  no-undo.      
      enumerator = ultraGrid1:DisplayLayout:Bands[bandKey]:GetRowEnumerator(Infragistics.Win.UltraWinGrid.GridRowType:DataRow):GetEnumerator().      
      do while enumerator:moveNext():
         gridRow = cast(enumerator:Current,Infragistics.Win.UltraWinGrid.UltraGridRow).
         gridRow:RefreshSortPosition().
      end.    
      catch e as System.InvalidOperationException :
         /* nothing - moveNext failed because we changed position */
      end catch. 
  end method.   

If you know the deleted row's ordinal position in the grid you might use the Index property as follows:

method public void resortRow(bandKey as char,pos as int):
      define variable enumerator as System.Collections.IEnumerator  no-undo.
      define variable gridRow    as Infragistics.Win.UltraWinGrid.UltraGridRow  no-undo.
      
      enumerator = ultraGrid1:DisplayLayout:Bands[bandKey]:GetRowEnumerator(Infragistics.Win.UltraWinGrid.GridRowType:DataRow):GetEnumerator().      
      do while enumerator:moveNext():
         gridRow = cast(enumerator:Current,Infragistics.Win.UltraWinGrid.UltraGridRow).
         if gridrow:Index = pos then 
         do:
            gridRow:RefreshSortPosition().
            return.
         end.   
      end.          
  end method.

Another alternative is to delete the row from the grid BEFORE the query is opened. The advantage of doing this before the grid has changed is that you only need to know the deleted row's position in the query and not the position in the grid. The following code expects the deleted query postion and uses the 0 based ListIndex to figure out which row to delete.

 method public void rowDeleted(bandKey as char,pos as integer):
      define variable enumerator as System.Collections.IEnumerator  no-undo.
      define variable gridRow    as Infragistics.Win.UltraWinGrid.UltraGridRow  no-undo.
      enumerator = ultraGrid1:DisplayLayout:Bands[bandKey]:GetRowEnumerator(Infragistics.Win.UltraWinGrid.GridRowType:DataRow):GetEnumerator().
      do while enumerator:moveNext():
          gridRow = cast(enumerator:Current,Infragistics.Win.UltraWinGrid.UltraGridRow).
          if gridRow:ListIndex + 1 = pos then
          do:
              gridRow:Delete(no) no-error.
              return.
          end.    
      end.     
  end method.

Note that the row is in a bad state at this point, and any operations may cause record not avail errors. The no-error seems to deal with this. If you call this BEFORE the record delete you do not need the no-error, but it may be hard to recover if the record delete should fail.

----

Your code is of course a simplified sample, but my assumption is that the grid is not in charge of the delete.

This did not appear to alter my results

The first example worked with a little tweaking.  The RefreshSortPosition was throwing the exception, as noted, so I created a second copy of collection and instead of using the MoveNext I traversed through all of the rows and invoked RefreshSortPosition.  The expanded state of some of the groups were wrong after this so I also added code to get the expanded rows and after refreshing the sort I set the states back to expanded if the group still existed.  The code is neither optimized nor fully tested but it appears to be working.

    DEFINE VARIABLE enumerator AS System.Collections.IEnumerator                    NO-UNDO.
    DEFINE VARIABLE gridRow    AS Infragistics.Win.UltraWinGrid.UltraGridRow        NO-UNDO.
    DEFINE VARIABLE groupByRow AS Infragistics.Win.UltraWinGrid.UltraGridGroupByRow NO-UNDO.
    
    enumerator = ultraGrid1:DisplayLayout:Bands[0]:GetRowEnumerator(Infragistics.Win.UltraWinGrid.GridRowType:GroupByRow):GetEnumerator().
    
    DO WHILE enumerator:moveNext():
      
      groupByRow = CAST(enumerator:Current,Infragistics.Win.UltraWinGrid.UltraGridGroupByRow).
      
      IF VALID-OBJECT(groupByRow) AND
        groupByRow:Expanded = YES THEN
      DO:
        CREATE ttExpandedGroups.
        ASSIGN
          ttExpandedGroups.rowValue = groupByRow:Value.
      END.
    END.
    
    hQuery:query-open().
          
    enumerator = ultraGrid1:DisplayLayout:Bands[0]:GetRowEnumerator(Infragistics.Win.UltraWinGrid.GridRowType:DataRow):GetEnumerator().
          
    DO WHILE enumerator:moveNext():
      
      gridRow = CAST(enumerator:Current,Infragistics.Win.UltraWinGrid.UltraGridRow).
      
      IF VALID-OBJECT(gridRow) THEN
      DO:
        CREATE ttGridRow.
        ASSIGN
          ttGridRow.row = gridRow.
      END.
    END.
    
    FOR EACH ttGridRow EXCLUSIVE-LOCK:
    
      gridRow = CAST(ttGridRow.row,Infragistics.Win.UltraWinGrid.UltraGridRow).
      gridRow:RefreshSortPosition().
      
      DELETE ttGridRow.
            
    END.
    
    FOR EACH ttExpandedGroups EXCLUSIVE-LOCK:
      enumerator = ultraGrid1:DisplayLayout:Bands[0]:GetRowEnumerator(Infragistics.Win.UltraWinGrid.GridRowType:GroupByRow):GetEnumerator().
    
      DO WHILE enumerator:moveNext():
      
        groupByRow = CAST(enumerator:Current,Infragistics.Win.UltraWinGrid.UltraGridGroupByRow).
        
        OUTPUT TO j:\employee\bheavican\uom.txt APPEND.
        PUT UNFORMATTED ttExpandedGroups.rowValue:ToString() SKIP.
        OUTPUT CLOSE.
      
        IF VALID-OBJECT(groupByRow) AND
          Progress.Util.EnumHelper:Equals(groupByRow:Value,CAST(ttExpandedGroups.rowValue,System.Object)) AND
          groupByRow:IsExpanded = NO AND
          groupByRow:IsExpandable = YES THEN
          groupByRow:Expanded = YES.
      END.
      
      DELETE ttExpandedGroups.
    END.